Overcast Component Plugin

 

The Overcast Component does not provide any fine-grained business logic when executing a scenario. However, as you can see Overcast Components accessing backend data by reference,  Enhancement Points are available. This page describes the Overcast Component Plugin concept as an enhancement point.

 

Apex Class templates can be found Overcast Component Plugin Template.

 

Overall flow

The timing at which each Plugin method is executed in a typical component (Non-Post type components, or components that are not "Auto Run")  is shown in the sequence diagram.

 

 

  1. afterComponentMetadataLoaded
  2. afterReferenceValuesLoaded (v2) or (v3)
  3. beforeScenarioCall and beforeScenarioCall (for Merged data)
  4. (Scenario Execution)
  5. afterScenarioCall

  6. beforeReturningData

 

The Post component and components that are not "Auto Run" is the same as the sequence above when the scenario is executed, but each method of the plug-in is called even before the scenario is executed.

 

  1. afterComponentMetadataLoaded
  2. afterReferenceValuesLoaded (v2) or (v3)

 

Specific examples of each method

Example of beforeScenarioCall()

It is mainly implemented to modify the data before sending it to the backend.

 

e.g. When no value is passed to BAPI_SALESORDER_GETLIST.CUSTOMER_NUMBER, this BAPI will try to bring all the data. To prevent this, set the Dummy parameter if there is no data in CUSTOMER_NUMBER to prevent getting all the data.

 

    global void beforeScenarioCall(Id recordId, Map<String, Object> referenceFieldValues, Map<String, Object> importParameters, Map<String, Object> settings) {
        if (!importParameters.containsKey('BAPI_SALESORDER_GETLIST')) {
            return;
        }
        Map<String,Object> getList = (Map<String,Object>)importParameters.get('BAPI_SALESORDER_GETLIST');
        if (getList.containsKey('CUSTOMER_NUMBER') && String.isBlank((String)getList.get('CUSTOMER_NUMBER'))) {
            getList.put('CUSTOMER_NUMBER', 'DUMMY_BP');
        }
        return;
    }

 

Example of afterScenarioCall()

It is mainly used to modify the data returned from Backend.

 

e.g. When the PO Number is empty, "-" will be displayed.

 

    global void afterScenarioCall(Map<String, Object> returnedData, overcast.ComponentDefinition.Component cmp, Map<String, Object> settings) {
        if (!returnedData.containsKey('SALES_ORDERS')) {
            return;
        }
        List<Object> salesOrders = (List<Object>)returnedData.get('SALES_ORDERS');
        for (Object salesOrder : salesOrders) {
            Map<String,Object> orderMap = (Map<String,Object>)salesOrder;
            if (String.isBlank((String)orderMap.get('PURCH_NO'))) {
                orderMap.put('PURCH_NO', '-');
            }
        }
    }

 

Example of afterComponentMetadataLoaded()

This method is mainly used to control the input of Filter and Post-based Components.

 

e.g. in SAP Sales Order List (sapSalesOrders) has 2 input field, and If you want to hide the MATERIAL filter only when it is executed on Opportunity.

 

    global void afterComponentMetadataLoaded(Id recordId, overcast.ComponentDefinition.Component cmp) {
        overcast.ComponentDefinition.Section section = cmp.findSection('BAPI_SALESORDER_GETLIST');
        if (section == null) {
            return;
        }
        overcast.ComponentDefinition.Field field = section.findField('MATERIAL');
        if (field == null) {
            return;
        }
        System.debug(recordId.getSObjectType().getDescribe().getName());
        if (recordId.getSObjectType().getDescribe().getName() == 'Opportunity') {
            field.display = false;
        }
    }
 

Result:

 

Run on Account:

 

Run on Opportunity

 

 

Example of afterReferenceValuesLoaded()

Used when you want to dynamically add, remove, or change the value of ReferenceValues at runtime.

 

e.g.  If you want to set default value (1400-100) to the MATERIAL field only when it is executed on Opportunity.

 

    global void afterReferenceValuesLoaded(Id recordId, String componentName, Map<String, Map<String, Object>> referenceValues)
    {
        if (!referenceValues.containsKey('BAPI_SALESORDER_GETLIST')) {
            return;
        }
        Map<String,Object> getList = referenceValues.get('BAPI_SALESORDER_GETLIST');
        if (recordId.getSObjectType().getDescribe().getName() == 'Opportunity') {
            if (!getList.containsKey('MATERIAL')) {
                getList.put('MATERIAL', '1400-100');
            }
        }
        return;
    }

 

Result:

 

Run on Account

 

Run on Opportunity